C-style preprocessor directives

In this section:

Syntax

#define symbol text

#elif condition

#else

#endif

#error "message"

#if condition

#ifdef symbol

#ifndef symbol

#include {"filename" | <filename>}

#message "message"

#undef symbol

Parameters

`condition`	An absolute assembler expression, see Expressions, operands, and operators. The expression must not contain any assembler labels or symbols, and any non-zero value is considered as true. The C preprocessor operator `defined` can be used.
`filename`	Name of file to be included or referred.
`message`	Text to be displayed.
`symbol`	Preprocessor symbol to be defined, undefined, or tested.
`text`	Value to be assigned.

Description

The assembler has a C-style preprocessor that is similar to the C89 standard.

Note

The preprocessor expressions use the same precedence rules as the assembler operators.

These C-language preprocessor directives are available:

Directive	Description
`#define`	Assigns a value to a preprocessor symbol.
`#elif`	Introduces a new condition in an `#if...#endif` block.
`#else`	Assembles instructions if a condition is false.
`#endif`	Ends an `#if`, `#ifdef`, or `#ifndef` block.
`#error`	Generates an error.
`#if`	Assembles instructions if a condition is true.
`#ifdef`	Assembles instructions if a preprocessor symbol is defined.
`#ifndef`	Assembles instructions if a preprocessor symbol is undefined.
`#include`	Includes a file.
`#message`	Generates a message on standard output.
`#pragma`	This directive is recognized but ignored.
`#undef`	Undefines a preprocessor symbol.

Table 153. C-style preprocessor directives

You must not mix assembler language and C-style preprocessor directives. Conceptually, they are different languages and mixing them might lead to unexpected behavior, as an assembler directive is not necessarily accepted as a part of the C preprocessor language.

Note

The preprocessor directives are processed before other directives. As an example, avoid constructs like:

redef       macro                   ; Avoid the following!
#define \1 \2
            endm

because the \1 and \2 macro arguments are not available during the preprocessing phase.

Defining and undefining preprocessor symbols

Use #define to define a value of a preprocessor symbol.

#define symbol value

Use #undef to undefine a symbol—the effect is as if it had not been defined.

Conditional preprocessor directives

Use the #if...#else...#endif directives to control the assembly process at assembly time. If the condition following the #if directive is not true, the subsequent instructions will not generate any code (that is, it will not be assembled or syntax checked) until an #endif or #else directive is found.

All assembler directives (except for END) and file inclusion can be disabled by the conditional directives. Each #if directive must be terminated by an #endif directive. The #else directive is optional and, if used, must be inside an #if...#endif block.

#if...#endif and #if...#else...#endif blocks can be nested to any level.

Use #ifdef to assemble instructions up to the next #else or #endif directive only if a symbol is defined.

Use #ifndef to assemble instructions up to the next #else or #endif directive only if a symbol is undefined.

This example defines the labels tweak and adjust. If adjust is defined, then register R0 is decremented by an amount that depends on adjust, for example 30 when adjust is 3.

            name    calibrate
            extern  calibrationConstant
            section MYCODE:CODE(2)
            arm

#define     tweak  1
#define     adjust 3

calibrate   ldr     r0,calibrationConstant
#ifdef      tweak
#if         adjust==1
            subs    r0,r0,#4
#elif       adjust==2
            subs    r0,r0,#20
#elif       adjust==3
            subs    r0,r0,#30
#endif
#endif      /* ifdef tweak */
            str     r0,calibrationConstant
            bx      lr

            end

Including source files

Use #include to insert the contents of a header file into the source file at a specified point.

#include"filename" and #include <filename> search these directories in the specified order:

The source file directory. (This step is only valid for #include "filename".)
The directories specified by the -I option, or options. The directories are searched in the same order as specified on the command line, followed by the ones specified by environment variables.
The current directory, which is the same as where the assembler executable file is located.
The automatically set up library system include directories. See -g.

This example uses #include to include a file defining macros into the source file. For example, these macros could be defined in Macros.inc:

; Exchange registers a and b.
; Use the register c for temporary storage.

xch         macro   a,b,c
            movs    c,a
            movs    a,b
            movs    b,c
            endm

The macro definitions can then be included, using #include, as in this example:

            name    includeFile
            section MYCODE:CODE(2)
            arm

; Standard macro definitions.
#include "Macros.inc"

xchRegs     xch     r0,r1,r2
            bx      lr

            end

Comments in C-style preprocessor directives

If you make a comment within a define statement, use:

the C comment delimiters /* ... */ to comment sections
the C++ comment delimiter // to mark the rest of the line as comment.

Do not use assembler comments within a define statement as it leads to unexpected behavior.

This expression evaluates to 3 because the comment character is preserved by #define:

#define x 3    ; This is a misplaced comment.

            module  misplacedComment1
expression  equ     x * 8 + 5
            ;...
            end

This example illustrates some problems that might occur when assembler comments are used in the C-style preprocessor:

#define five  5     ; This comment is not OK.
#define six   6     // This comment is OK.
#define seven 7     /* This comment is OK. */

            module  misplacedComment2
            section MYCONST:CONST(2)

            DC32    five, 11, 12
; The previous line expands to:
;          "DC32    5     ; This comment is not OK., 11, 12"

            DC32    six + seven, 11, 12
; The previous line expands to:
;          "DC32    6 + 7, 11, 12"
            end

IAR Embedded Workbench for Arm 9.70.x