Skip to main content

IAR Embedded Workbench for Arm 9.70.x

C形式のプリプロセッサディレクティブ

このセクションの内容:
構文

#define symbol text

#elif condition

#else

#endif

#error "message"

#if condition

#ifdef symbol

#ifndef symbol

#include {"filename" | <filename>}

#message "message"

#undef symbol

パラメータ

condition

絶対アセンブラ式は式、オペランド、演算子を参照してください。

式に、アセンブララベルまたはシンボルを含めることは一切できず、ゼロ以外の値はすべて真と見なされます。Cプリプロセッサ演算子definedが使用されます。

filename

インクルードされるか参照されるファイルの名前。

message

表示されるテキスト。

symbol

定義、定義取り消し、または テストされるプリプロセッサシンボル。

text

割り当てられる値。

説明

アセンブラには、C89標準にと似たようなC形式のプリプロセッサがあります。

注記

プリプロセッサ式は、アセンブラ演算子と同じ優先順位規則を使用します。

以下のC言語プリプロセッサディレクティブを使用できます。

ディレクティブ

説明

#define

プリプロセッサシンボルに値を割り当てます。

#elif

#if...#endifブロックに新しい条件を導入します。

#else

条件が偽の場合に命令をアセンブルします。

#endif

#if、#ifdef、または#ifndefブロックを終了させます。

#error

エラーを生成します。

#if

条件が真の場合に命令をアセンブルします。

#ifdef

プリプロセッサシンボルが定義されている場合に命令をアセンブルします。

#ifndef

プリプロセッサシンボルが定義されていない場合に命令をアセンブルします。

#include

ファイルをインクルードします。

#message

標準出力上にメッセージを生成します。

#pragma

を参照してください。このディレクティブは、認識はされますが、無視されます。

#undef

プリプロセッサシンボルの定義を取り消します。

表153 C形式のプリプロセッサディレクティブ  


アセンブラ言語とC形式のプリプロセッサディレクティブを混在させないでください。これらは概念的に異なる言語です。アセンブラディレクティブはCプリプロセッサ言語の一部として受け入れられない場合があるため、これらを混在させると、予期しない動作の原因となる可能性があります。

注記

プリプロセッサディレクティブは、他のディレクティブの前に処理されます。たとえば、以下のような構文を避けてください。

redef       macro                   ; Avoid the following!
#define \1 \2
            endm

これは、\1と\2というマクロ引数は前処理フェーズで使用できないためです。

プリプロセッサシンボルの定義と定義取消し

プリプロセッサシンボルを定義するには、#defineを使用します。

#define symbol value

シンボルの定義を取り消すには#undefを使用します。その結果、定義されていなかったのと同じになります。

条件付きプリプロセッサディレクティブ

アセンブリ時にアセンブリプロセスを制御するには、#if...#else...#endifディレクティブを使用します。#ifディレクティブの後の条件が真ではない場合、#endifまたは#elseディレクティブが検出されるまで、後続の命令はコードを一切生成しません(つまり、アセンブルも構文チェックも行われません)。

(ENDを除く)すべてのアセンブラディレクティブおよびファイルのインクルードは、条件付きディレクティブで無効にできます。各#ifディレクティブは#endifディレクティブで終了する必要があります。#elseディレクティブは任意指定であり、使用する場合は、#if...#endifブロック内に指定する必要があります。

#if...#endifブロックと#if...#else...#endifブロックは、任意のレベルまでネストできます。

シンボルが定義されている場合に限り、次の#elseまたは#endifディレクティブまで命令をアセンブルするには、#ifdefを使用します。

シンボルが定義されていない場合に限り、次の#elseまたは#endifディレクティブまで命令をアセンブルするには、#ifndefを使用します。

以下の例は、tweakとadjustというラベルを定義します。adjustが定義されている場合、レジスタR0はadjustに応じた数値だけデクリメントされます（adjustが3であれば30）。

            name    calibrate
            extern  calibrationConstant
            section MYCODE:CODE(2)
            arm

#define     tweak  1
#define     adjust 3

calibrate   ldr     r0,calibrationConstant
#ifdef      tweak
#if         adjust==1
            subs    r0,r0,#4
#elif       adjust==2
            subs    r0,r0,#20
#elif       adjust==3
            subs    r0,r0,#30
#endif
#endif      /* ifdef tweak */
            str     r0,calibrationConstant
            bx      lr

            end
ソースファイルのインクルード

#includeを使用して、ヘッダファイルの内容を、ソースファイル中の指定した箇所に挿入します。

#include"filename"と#include <filename>は、以下のディレクトリを指定の順に検索します。

  1. ソースファイルディレクトリ (この手順は、#include "filename"でのみ有効です)。

  2. -Iオプションで指定されたディレクトリ ディレクトリは、コマンドラインで指定したものと同じ順序で検索され、続いて環境変数で指定したものが検索されます。

  3. 現在のディレクトリ。アセンブラの実行可能ファイルがあるディレクトリと同じです。

  4. 自動的に設定されたライブラリシステムには、ディレクトリが含まれます。-gを参照してください。

以下の例では、ファイル定義マクロをソースファイルにインクルードするために#includeが使用されます。たとえば、次のようなマクロをMacros.incに定義できます。

; Exchange registers a and b.
; Use the register c for temporary storage.

xch         macro   a,b,c
            movs    c,a
            movs    a,b
            movs    b,c
            endm

続いて、次の例のように、#includeを使用してマクロ定義をインクルードできます。

            name    includeFile
            section MYCODE:CODE(2)
            arm

; Standard macro definitions.
#include "Macros.inc"

xchRegs     xch     r0,r1,r2
            bx      lr

            end
エラー表示

ユーザ定義テストなどでアセンブラに強制的にエラーを生成させるには、#errorを使用します。

#pragmaの無視

#pragma行は、Cおよびアセンブラと共通するヘッダファイルを使用しやすくなるように、アセンブラにより無視されます。

C 形式のプリプロセッサディレクティブでのコメント

定義文でコメントを記述するには、以下の形式を使用します。

  • コメントセクションには、C形式のコメント区切り文字/* ... */を使用します。

  • 残りの行をコメントとしてマーキングするには、C++コメント区切り文字//を使用します。

定義された文の中でアセンブラコメントを使用すると、予期しない動作をする可能性があるため、使用しないでください。

以下の式では、コメント文字が#defineによって保護されているため、評価結果は3となります。

#define x 3    ; This is a misplaced comment.

            module  misplacedComment1
expression  equ     x * 8 + 5
            ;...
            end

以下の例は、C形式のプリプロセッサでアセンブラコメントを使用すると発生する可能性のある問題の一部を示します。

#define five  5     ; This comment is not OK.
#define six   6     // This comment is OK.
#define seven 7     /* This comment is OK. */

            module  misplacedComment2
            section MYCONST:CONST(2)

            DC32    five, 11, 12
; The previous line expands to:
;          "DC32    5     ; This comment is not OK., 11, 12"

            DC32    six + seven, 11, 12
; The previous line expands to:
;          "DC32    6 + 7, 11, 12"
            end