Section control directives

In this section:

Syntax

ALIGN align [, value ]

ALIGNRAM align

ASEGN section [: type ] [: flag ] [, address ]

EVEN [ value ]

ODD [ value ]

RSEG section [: type ] [: flag ] [( align )]

SECTION section [: type ] [: flag ] [( align )]

SECTION_TYPE type-expr {, flags-expr }

Parameters

`address`	Address where this section part is placed.
`align`	The power of two to which the address should be aligned.The default align value is 0, except for code sections where the default is 1.
`flag`	`ROOT`, `NOROOT` `ROOT` (the default mode) indicates that the section fragment must not be discarded. `NOROOT` means that the section fragment is discarded by the linker if no symbols in this section fragment are referred to. Normally, all section fragments except startup code and interrupt vectors should set this flag.
	`REORDER`, `NOREORDER` `NOREORDER` (the default mode) starts a new fragment in the section with the given name, or a new section if no such section exists. `REORDER` starts a new section with the given name.
`section`	The name of the section. The section name is a user-defined symbol that follows the rules described in Symbols.
`type`	The memory type, which can be either `CODE`, `CONST`, or `DATA`.
`value`	4-byte value used for padding. The default is zero.
`type-expr`	A constant expression that identifies the ELF type of the section.
`flags-expr`	A constant expression that identifies the ELF flags of the section.

Description

The section directives control how code and data are located. For information about the restrictions that apply when using a directive in an expression, see Expression restrictions.

Directive	Description	Expression restrictions
`ALIGN`	Aligns the program location counter by inserting .	No external references Absolute
`ALIGNRAM`	Aligns the program location counter.	No external references Absolute
`ASEGN`	Begins a named absolute section.	No external references Absolute
`EVEN`	Aligns the program counter to an even address.	No external references Absolute
`ODD`	Aligns the program counter to an odd address.	No external references Absolute
`RSEG`	Begins an ELF section—alias to `SECTION`.	No external references Absolute
`SECTION`	Begins an ELF section.	No external references Absolute
`SECTION_TYPE`	Sets ELF type and flags for a section.

Table 124. Section control directives

Beginning a relocatable section

Use SECTION (or RSEG) to start a new section. The assembler maintains separate location counters (initially set to zero) for all sections, which makes it possible to switch sections and mode anytime without having to save the current program location counter.

Note

The first instance of a SECTION or RSEG directive must not be preceded by any code generating directives, such as DC8 or DS8, or by any assembler instructions.

To set the ELF type, and possibly the ELF flags for the newly created section, use SECTION_TYPE. By default, the values of the flags are zero. For information about valid values, refer to the ELF documentation.

In the following example, the data following the first SECTION directive is placed in a relocatable section called TABLE.

The code following the second SECTION directive is placed in a relocatable section called CODE:

            module  calculator
            extern  operator
            extern  addOperator, subOperator
        
            section TABLE:CONST(8)
            data
operatorTable:
            dc8     addOperator, subOperator
        
            section CODE:CODE(2)
            code
calculator: ld.w    operator[r0],r1
            ld.bu   0[r1],r1
            ld.bu   operatorTable[r0],r7
            cmp     r1,r7
            be      add
            ld.bu   operatorTable+1[r0],r7
            cmp     r1,r7
            be      sub
            ;...
            dispose     0,{lp},[lp]

add:        ;...
            dispose     0,{lp},[lp]

sub:        ;...
            dispose     0,{lp},[lp]
            end

Aligning a section

Use ALIGN to align the program location counter to a specified address boundary. You do this by specifying an expression for the power of two to which the program counter should be aligned. That is, a value of 1 aligns to an even address, and a value of 2 aligns to an address evenly divisible by 4.

The alignment is made relative to the section start—normally this means that the section alignment must be at least as large as that of the alignment directive to give the desired result.

ALIGN aligns by inserting zero/filled bytes, up to a maximum of 255. The EVEN directive aligns the program counter to an even address (which is equivalent to ALIGN 1), and the ODD directive aligns the program location counter to an odd address. The value used for padding bytes must be within the range 0 to 255.

Use ALIGNRAM to align the program location counter by incrementing it—no data is generated. The parameter align can be within the range 0 to 8.

This example starts a section, moves to an even address, and adds some data. It then aligns to a 64-byte boundary before creating a 64-byte table.

            name    alignment
            section DATA:DATA ; Start a relocatable data segment.
            even              ; Ensure it is on an even boundary.
            data16            ; Disassembled as 16-bit data
target      dc16    1         ; target and best will be on an
best        dc16    1         ; even boundary.
            data8             ; Disassembled as 8-bit data
            align   6         ; Now, align to a 64-byte boundary,
results     ds8     64        ; and create a 64-byte table.
            end

IAR Embedded Workbench for RH850 3.20.x