Assembler control directives

In this section:

Syntax

/*comment*/

//comment

CASEOFF

CASEON

ERROR "message"

.option {norelax|norvc|pop|push|relax|rvc}

RADIX expr

Parameters

`comment`	Comment ignored by the assembler.
`expr`	Default base—default 10 (decimal).
`message`	Text to be displayed.
`norelax`	Disables the link-time instruction relaxation.
`norvc`	Prevents the assembler from converting normal and pseudo-instructions to compressed instructions. (Note that compressed instructions can still be used after `.option norvc`.)
`pop`	Restores the options saved using `push`.
`push`	Saves the current options to a stack for future restoration.
`relax`	Enables the link-time instruction relaxation.
`rvc`	Allows the assembler to convert normal and pseudo-instructions to compressed instructions. The is the default mode.

Description

These directives provide control over the operation of the assembler. For information about the restrictions that apply when using a directive in an expression, see Expression restrictions.

Directive	Description	Expression restrictions
`/comment/`	C-style comment delimiter.
`//`	C++ style comment delimiter.
`CASEOFF`	Disables case sensitivity.
`CASEON`	Enables case sensitivity.
`ERROR`	Generates an error.
`.option`	Makes a setting that controls the operation of the assembler.
`RADIX`	Sets the default base on all numeric values.	No forward references No external references Absolute Fixed

Table 131. Assembler control directives

Use /*...*/ to comment sections of the assembler listing.

Use // to mark the rest of the line as comment.

Use RADIX to set the default base for constants. The default base is 10.

Controlling case sensitivity

Use CASEON or CASEOFF to turn case sensitivity on or off for user-defined symbols. By default, case sensitivity is on.

When CASEOFF is active all symbols are stored in upper case, and all symbols used by the linker should be written in upper case in the linker definition file.

When CASEOFF is set, label and LABEL are identical in this example:

            module  caseSensitivity1
            rseg    CODE:CODE

            caseoff
label       nop                 ; Stored as "LABEL".
            j       LABEL
            end

The following will generate a duplicate label error:

            module  caseSensitivity2
            rseg    CODE:CODE

            caseoff
label       nop                 ; Stored as "LABEL".
LABEL       nop                 ; Error, "LABEL" already defined.
            end

Generating errors

Use ERROR to force the assembler to generate an error. It us useful in, for example, macros:

MyMacro     macro
            if \0 == 7
            error "Wrong first parameter"
            endif
            endm

Defining comments

This example shows how /*...*/ can be used for a multi-line comment:

/*
Program to read serial input.
Version 1: 19.2.25
Author: mjp
*/

Disabling and re-enabling link-time instruction relaxation

This example assumes that instruction relaxation is enabled initially. It first saves the current state of options. Then it disables instruction relaxation, executes two instructions, and after that restores instruction relaxation again:

.option push
.option norelax
la a0, myLabel  // will be a lui/addi pair, and not relaxed
                // to addi a0, gp, <offset>
call myFunc     // will be a auipc/jalr pair, even if a jal
                // would have reached myFunc
.option pop

For more information about instruction relaxation, see Instruction relaxation. the .

Changing the base

To set the default base to 16:

            module  radix
            rseg    CODE:CODE

            radix   16            ; With the default base set
            addi    t0, x0, 12    ; to 16, the immediate value
            ;...                  ; of the load instruction is
                                  ; interpreted as 0x12.

; To reset the base from 16 to 10 again, the argument must be
; written in hexadecimal format.

            radix   0x0a          ; Reset the default base to 10.
            addi    t0, x0, 12    ; Now, the immediate value of
            ;...                  ; the load instruction is
                                  ; interpreted as 0x0c.
            end

IAR Embedded Workbench for RISC-V 3.40